Rozmowy o wszystkich innych systemach.
Awatar użytkownika

pc.qwerty

Zasłużony użytkownik
Posty: 3272
Rejestracja: 01 lip 2010, 11:28
    Windows Vista Firefox

Post10 wrz 2011, 14:27

:trollface: ıʞuoɹpǝıq z ɐɹnʇɐıʍɐlʞ oʇ ʇsǝɾ oqlɐ
There is no cloud. It's just someone else's computer.

Awatar użytkownika

Ult1me

Administrator
Posty: 2425
Rejestracja: 05 sie 2008, 14:48
Lokalizacja: Wrocław
Kontaktowanie:
    Windows 7 Opera

Post10 wrz 2011, 14:29

(؛ ǝıuzɔǝıuoʞǝıu
Komputery:
Spoiler: pokaż
Laptop (mój główny komputer): Acer Aspire 5750G | Intel Core i3 2330M (Sandy Bridge) 0.8-2.2GHz | Intel HM65 | 6GB RAM DDR3 | Intel HD Graphics 3000 + nVidia GeForce GT540M (nVidia Optimus) | Crucial MX100 256GB SSD | Broadcom 802.11n Network Adapter | Broadcom NetLink Gigabit Ethernet | Realtek ALC269 (+Dolby Advanced Audio)

Laptop służbowy: HP ProBook

Komputer brata (mój stary): Intel Pentium DualCore E6300 (2x 2.8@1.6-3.25 GHz EIST, 64bit, Intel-VT) | Gigabyte EP43T-UD3L (P43, ICH10) | 2x2 GB RAM DDR3 1066MHz GoodRAM | Palit GeForce GT220 | 2x500 GB (Seagate + SpinPoint F3)

Stacja do napraw: Intel Pentium 4 630 (3.00@2.43 GHz, 64bit, HT, Prescott) | ASUS P5GPL (Intel i915, ICH6) | 2x512 MB RAM DDR1 Kingston (PC-3200) | Gainward GeForce 7300 GT 256 MB DDR2 | jakiś dysk :)

Komputer na części: Intel Pentium III 600 MHz Slot 1 | ASUS P3B-F | 128 MB SDR SDRAM | GeForce 2 MX400 (?) | Seagate 8.4GB PATA

Lumia 625


Dowódca Grupy Odwetowej Mafii C-QUAM, łączącej fanów fal długich, średnich i krótkich, nak***iania kabli j**anych, France Bleu Alsace, The Mighty KBC, Voice of Korea, Warszawskiej Radiostacji Centralnej z najwyższym masztem świata Konstantynowie koło Gąbina, oraz Radiowego Centrum Nadawczego z prawie najwyższymi masztami w Solcu Kujawskim

Awatar użytkownika

radio

Posty: 11
Rejestracja: 05 wrz 2011, 20:48
    Windows 2003 Opera

Post10 wrz 2011, 16:55

CID\SERVER\PANORAMA

Kod: Zaznacz cały

/*******************************************************/
/* Before running, SET LANG= to the correct language.  */
/* It may already be correctly set in your CONFIG.SYS. */
/* For examples:                                       */
/* SET LANG=ar_AA for Arabic                           */
/* SET LANG=pt_BR for Brazil                           */
/* SET LANG=zh_CN for Simplified Chinese               */
/* SET LANG=de_DE for Germany                          */
/* SET LANG=da_DK for Denmark                          */
/* SET LANG=es_ES for Spain                            */
/* SET LANG=el_GR for Greece                           */
/* SET LANG=fi_FI for Finland                          */
/* SET LANG=fr_FR for France                           */
/* SET LANG=iw_IL for Israel                           */
/* SET LANG=it_IT for Italy                            */
/* SET LANG=ja_JP for Japan                            */
/* SET LANG=ko_KR for Korea                            */
/* SET LANG=nl_NL for Netherlands                      */
/* SET LANG=no_NO for Norway                           */
/* SET LANG=sv_SE for Sweden                           */
/* SET LANG=zh_TW for Taiwan                           */
/* SET LANG=en_US for English (default)                */
/*******************************************************/

/*****************************************
* Intialize Rexxutil Functions
******************************************/

  call RxFuncAdd 'SysLoadFuncs' , 'REXXUTIL', 'SysLoadFuncs'

  signal on syntax name MsgExit

  call SysLoadFuncs

  numeric digits 12

/******************************************
* Define message ids from *mid*.h
*******************************************/

  MSG_NO_ERROR               =    0
  MSG_SYSINIT_BOOT_NOT_FD    = 1475
  MSG_INCORRECT_DOSVER       = 1210
  MSG_NO_META_MATCH          =  257
  MSG_PRINT_FILE_NOT_FOUND   = 1533
  MSG_COMP_INVALID_PATH      = 1171
  MSG_BOOT_MUST_RESTART      = 1716
  MSG_INSTALL_UNSUCCESSFUL   = 1975
  MSG_INSTALL_HY_HDR         = 1976
  MSG_PROC_NOT_FOUND         =  127
  MSG_REP_SOUR_PATH_REQ      = 1137
  MSG_SYS_INV_DRIVE          = 1461
  MSG_CHCP_INVALID_PARAMETER = 1761
  MSG_UNP_INSERT_PI          = 1218
  MSG_ERR_PROC_ARG           = 1249
  MSG_MBS_INVALID_COMMAND    =  872
  MSG_USAGE                  =  734
  MSG_BAD_UNIT               =   20
  MSG_CANNOT_MAKE            =   82
  REXX_FUNCTION_NOT_FOUND    =   43
  SPTReboot                  = x2d('FE00',4)
  SPTRebootErr               = x2d('FE08',4)
  SPTWithErr                 = x2d('0008',4)

/*****************************************
* Initialized globals
******************************************/

  env = 'OS2ENVIRONMENT'
  lang = value('LANG',,env)
  nlv = SubStr(lang,4)
  if nlv = ''
  then nlv = 'en'
  parse source one two me
  if arg() == 0
  then cmdline = ''
  else cmdline = arg(1)
  srcPath = filespec('Drive', me) || filespec('Path', me)
  files = srcPath || nlv || '\*.*'
  if stream(files, 'c', 'query exists') = ''
  then nlv = 'en'
  if nlv == 'cn' or nlv == 'jp' or nlv == 'kr' or nlv = 'tw'
  then cs = 'dbcs'
  else cs = 'sbcs'
  if nlv == 'kr'
  then dos = 'kr'
  else dos = cs
  cidInst = ''

/*****************************************
* GRADD only globals
******************************************/

  GRADDKEYS    = 'ATI CHP DYN G_V GEN MGA NM S3 TRI VIRGE VGA'
  GRADDDSCS    = 'm64grdbb chpgrdbb dyngrdbb g_vgrdbb gengrdbb mgagrdbb nmgrdbb s3grdbb trigrdbb s3dgrdbb vgagrdbb'
  graddPackDSC = 'grdpack.dsc'

/*****************************************
* Set up Source Paths
******************************************/

  srcName = filespec('Name', me)

/*****************************************
* Set up default boot drive.
* GRADD is not supported on OS/2 Versions less than 3.0.
* Let us verify we have the right version now.
******************************************/

  parse value(SysOS2Ver()) with major '.' os2Ver
  rc = MSG_INCORRECT_DOSVER
  select
    when major < 2 then call MsgExit MyGetMsg(SysGetMessage(MSG_INCORRECT_DOSVER))
    when datatype(os2Ver) \= 'NUM' then call MsgExit MyGetMsg(SysGetMessage(MSG_INCORRECT_DOSVER))
    when os2Ver < 30 then call MsgExit MyGetMsg(SysGetMessage(MSG_INCORRECT_DOSVER))
    /* SysBootDrive() only works on WSeB level code */
    when os2Ver < 45 /* Before WSeB */
      then do
        /* We must make best "guess" */
        rc = MSG_NO_ERROR
        os2bootpath = SysSearchPath('PATH', 'os2boot')
        if os2bootpath == ''
        then do
          /* Maybe boot drive root is not in path! */
          os2bootpath = translate(value('PATH',,env))
          if os2bootpath \= ''
          then do
            first = pos(':\OS2;', os2bootpath)
            if first <= 0
            then os2bootpath = ''
            else do
              os2bootpath = substr(os2bootpath, first - 1, 2)
              bootDrive = filespec('drive', os2bootPath)
              file1 = bootDrive || '\os2boot'
              call SysFileTree file1,'file','F'
              if file.0 == 0
              then os2bootpath = ''
            end
          end
        end
        if os2bootpath == ''
        then do
          /* Maybe boot drive \OS2 has been renamed! */
          os2bootpath = SysSearchPath('PATH', 'unpack2.exe')
          if os2bootpath \= ''
          then do
            bootDrive = filespec('drive', os2bootPath)
            file1 = bootDrive || '\os2boot'
            call SysFileTree file1,'file','F'
            if file.0 == 0
            then os2bootpath = ''
          end
          if os2bootpath == ''
          then do
            /* Maybe unpack2 is not on boot drive! */
            os2bootpath = Directory()
            bootDrive = filespec('drive', os2bootPath)
            file1 = bootDrive || '\os2boot'
            call SysFileTree file1,'file','F'
            if file.0 == 0
            then call MsgExit SysGetMessage(MSG_SYSINIT_BOOT_NOT_FD)
          end
        end
      end
    otherwise /* WSeB or after */
      os2bootpath = SysBootDrive()
  end
  rc = MSG_NO_ERROR
  bootDrive = filespec('drive', os2bootPath)

/******************************************
* Verify options if any
*******************************************/

  if arg() == 0
    then call Usage
    else do
       parse value(cmdline) with tmp1 '/' option tmp2
       if option \= ''
       then do
          if translate(option) == 'U'
          then do
             cidInst = ' /u'
             cmdline = tmp1 || tmp2
          end
          else do
             say MyGetMsg(SysGetMessage(MSG_MBS_INVALID_COMMAND,, '"' || '/' || option || '"'))
             call Usage
          end
       end
       parse value(cmdline) with gradd srcTmp bootTmp junk
       if junk \= '' then call Usage
       if wordpos(translate(gradd), GRADDKEYS) == 0
         then call Usage
         else dscFile = word(GRADDDSCS, wordpos(translate(gradd), GRADDKEYS)) || '.dsc'
       if srcTmp \= ''
         then do
            if filespec('Drive',srcTmp) == strip(srcTmp, 'T', '\')
              then srcChk = srcTmp
              else srcChk = strip(srcTmp, 'T', '\') || '\'
            file1 = srcChk || srcName
            call SysFileTree file1, 'file', 'F'
            if file.0 == 0
              then do
                 say FileNotFound( file1 )
                 say MyGetMsg(SysGetMessage(MSG_CHCP_INVALID_PARAMETER,,srcTmp))
                 call Usage
              end
              else srcPath = srcChk
         end
       if bootTmp \= ''
         then do
            bootTmp   = strip(bootTmp, 'T', '\')
            file1 = bootTmp || '\OS2BOOT'
            call SysFileTree file1, 'file', 'F'
            if file.0 == 0
              then do
                 msg = MyGetMsg(SysGetMessage(MSG_SYSINIT_BOOT_NOT_FD))
                 parse value(msg) with first 'OS2BOOT' last
                 msg = first || '"' || file1 || '"' || last
                 say msg
                 say MyGetMsg(SysGetMessage(MSG_SYS_INV_DRIVE))
                 call Usage
              end
              else bootDrive = bootTmp
         end
    end
  if filespec('Drive', srcPath) \= strip(srcPath, 'T', '\')
  then srcDir = strip(srcPath, 'T', '\')
  else srcDir = srcPath

/*****************************************
* Set up Target Paths
******************************************/

  installDir = bootDrive || '\os2\install'
  restoreDir = installDir || '\vga'

/*****************************************
* Start logging
******************************************/

  call SysFileTree installDir, 'file', 'D'
  if file.0 == 0 then call MsgExit MyGetMsg(SysGetMessage(MSG_COMP_INVALID_PATH,,'"' || installDir || '"'))
  logFile = installDir || '\display.log'
  call SysFileTree logFile, 'file', 'F', ,'-----'
  startmsg = MyGetMsg(SysGetMessage(MSG_UNP_INSERT_PI,, SubStr(dscFile,1, pos('.', dscFile)-1 ) || ' ' ))
  cmd = 'parse value(startmsg) with . '''D2c(10)''' installmsg '''D2c(13)''' junk'
  interpret cmd
  installmsg = strip(installmsg)
  call LogIt '======================================================================'
  say installmsg
  call LogIt installmsg ' - ' Date('L')  Time()
  file1 = srcPath || 'build.lvl'
  call SysFileTree file1,'file','F'
  if file.0 == 0
  then call LogFileNotFound file1
  else '@type ' || file1 || ' >> ' || logFile

/*****************************************
* GRADD also requires a certain fixpak level for both version 3.x and 4.0.
* Let us verify we have the right levels now.
******************************************/

  rc = MSG_INCORRECT_DOSVER
  select
     when os2Ver < 40   /* Warp 3.0 needs fixpak 35 or later */
        then do
           needFPLevel = 8.259
        end
     when os2Ver < 45   /* Warp 4.0 needs fixpak 5 or later */
        then do
           needFPLevel = 9.029
        end
     otherwise          /* Releases after Warp 4.0 should be GRADD ready */
        do
           needFPLevel = 0
        end
  end
  parse value(GetGraddLevel(bootDrive || '\os2\dll\gre2vman.dll')) with graddLevel graddStamp

  if (GetFPLevel() >= needFPLevel)
  then do
     newStamp   = 1
  end
  else call MsgExit MyGetMsg(SysGetMessage(MSG_INCORRECT_DOSVER))
  rc = MSG_NO_ERROR

/*******************************************************
* Setup path and Copy required files to \os2\install
********************************************************/

  oldPath = value('PATH',,env)
  newPath = value('PATH', srcPath || ';' || oldPath, env)

  file1 = srcPath || 'unpack2.exe'
  call SysFileTree file1,'file','F'
  if file.0 == 0
  then call LogFileNotFound file1
  else call LogAndDoCmd 'copy ' || file1 || ' ' || installDir
  rc = MSG_NO_ERROR
  unpackFiles =                       'dspinstl.ex_'
  unpackFiles = unpackFiles || ' ' || 'inscfg32.dl_'
  unpackFiles = unpackFiles || ' ' || nlv || '\unpack'
  unpackFiles = unpackFiles || ' ' || nlv || '\vgamri'
  do i = 1 to words(unpackFiles)
    call LogAndDoCmd 'unpack2 ' || srcPath || word(unpackFiles, i) || ' ' || bootDrive
    if rc \= MSG_NO_ERROR then call MsgExit ""
  end
  call LogAndDoCmd 'unpack2 ' || srcPath || 'dspinstl.ex_ ' || restoreDir
  if rc \= MSG_NO_ERROR then call MsgExit ""
  call LogAndDoCmd 'copy ' || bootDrive || '\os2\dll\dspimri.dll ' || restoreDir
  if rc \= MSG_NO_ERROR then call MsgExit ""

/********************************************************
* Obtain .DSC file
*********************************************************/

  call SysFileTree installDir || '\' || dscFile, 'file', 'F'
  if file.0 == 0 then call MsgExit MyGetMsg(SysGetMessage(MSG_PRINT_FILE_NOT_FOUND,, '"' || installDir || '\' || dscFile || '"')),
                                   || MyGetMsg(SysGetMessage(MSG_NO_META_MATCH))
                 else parse value(file.1) with . . . . dscFile
  dscFile = installDir || '\' || FileSpec('Name', dscFile)

  if SysFileTree(bootDrive || '\os2\video.cfg','file','F',,'+****') == 0
    then call SysFileDelete bootDrive || '\os2\video.cfg'

  if translate(gradd) == 'VGA' then call SysIni ,'PM_DISPLAYDRIVERS','DEFAULTSYSTEMRESOLUTION','DELETE:'

  graddPackDSC = installDir || '\' || graddPackDSC
  parse value(GetGraddLevel(srcPath || 'gre2vman.dll')) with . tmpStamp
  if datatype(tmpStamp) == 'NUM' then newStamp = tmpStamp

  dspInstall = installDir || '\dspinstl.exe'

  '@' || dspInstall '/pk:other /s:' || srcDir,
                 || ' /t:' || bootDrive,
                 || ' /pd:' || strip(graddPackDSC),
                 || ' /l:' || logFile || cidInst

  '@' || dspInstall '/pk:svga /s:' || srcDir,
                 || ' /t:' || bootDrive,
                 || ' /pd:' || strip(dscFile),
                 || ' /l:' || logFile || cidInst

  if ( (rc == MSG_NO_ERROR) | ((cidInst \= '') & ( rc == SPTReboot)) )
    then call MsgExit MyGetMsg(SysGetMessage(MSG_BOOT_MUST_RESTART))
    else call MsgExit MyGetMsg(SysGetMessage(MSG_ERR_PROC_ARG,,dscFile))

/******************************************************
* Procedure for determining level of Gradd subsystem
*******************************************************/

GetGraddLevel: Procedure

   parse arg graddModule

   gtvVer = ''

   if stream(graddModule,'c', 'query exists') \= ''
   then do
       newQueue = RxQueue('Create')
       oldQueue = RxQueue('Set', newQueue)
       '@bldlevel 'graddModule '| rxqueue' newQueue
       do while queued() \=0
          parse upper pull tag data
          if tag == 'SIGNATURE:'
          then
             do while queued() \= 0
               parse upper pull tag data
               if tag == 'DESCRIPTION:'
                  then parse value(data) with  'V' gtvVer gtvStamp .
             end
       end
       call RxQueue 'Delete', newQueue
       call RxQueue 'Set', oldQueue
   end

   if datatype(gtvVer)   \= 'NUM' then gtvVer = 0
   if datatype(gtvStamp) \= 'NUM' then gtvStamp = 0

   return gtvVer gtvStamp

/******************************************************
* Procedure for determining fix pack level of system
*******************************************************/

GetFPLevel: Procedure

   newQueue = RxQueue('Create')
   oldQueue = RxQueue('Set', newQueue)
   '@ver /r | rxqueue' newQueue
   do while queued() \=0
      parse upper pull tag data
      if tag == 'REVISION'
      then leave
   end
   call RxQueue 'Delete', newQueue
   call RxQueue 'Set', oldQueue

   return data

/******************************************************
* Error message processing and exit
*******************************************************/

MsgExit:

   parse arg errmsg

   result = rc
   if rc == REXX_FUNCTION_NOT_FOUND
    then do
        say sigl'  +++      'SourceLine(sigl)
        say 'REX0043: 'ErrorText(REXX_FUNCTION_NOT_FOUND)
    end
    else do
      if errmsg == '' then errmsg = 'REXX' || right(rc,4,'0') || ': 'ErrorText(rc)
      say errmsg
      if ( (rc \= MSG_NO_ERROR) & ((cidInst \= '') & ( rc \= SPTReboot)) )
        then do
           exitmsg = MyGetMsg(SysGetMessage(MSG_INSTALL_UNSUCCESSFUL))
           say exitmsg
        end
      if symbol('logfile') == 'VAR'
        then do
           call LogIt errmsg
           if symbol('exitmsg') == 'VAR'
             then do
               call LogIt exitmsg
               say MyGetMsg(SysGetMessage(MSG_INSTALL_HY_HDR)) || ' ' || logfile
             end
        end
    end
   if rc == MSG_INCORRECT_DOSVER
   then '@pause && e ' || srcPath || nlv || '\readme.txt'
   if symbol('oldPath') == 'VAR' then call value 'PATH' , oldPath, env
   exit result

/******************************************************
* Safely write to logfile
*******************************************************/

LogAndDoCmd:

  call LogIt arg(1)
  '@' || arg(1) || ' >> ' || logfile || ' 2>&1'
  return

/******************************************************
* Log File Not Found
*******************************************************/

LogFileNotFound:

  call LogIt FileNotFound( arg(1) )
  return

/******************************************************
* File Not Found
*******************************************************/

FileNotFound:

  return MyGetMsg(SysGetMessage(MSG_PRINT_FILE_NOT_FOUND,, '"' || arg(1) || '"'))

/******************************************************
* Safely write to logfile
*******************************************************/

LogIt: Procedure expose logfile

  parse arg message
  call lineout logfile, message
  call stream logfile, 'c', 'close'
  return

/******************************************************
* Remove SYSXXXX: from messages
*******************************************************/

MyGetMsg: Procedure

  parse arg message
  if pos('SYS', word(message, 1)) == 1
    then parse arg . message
  return message

/*****************************************************
* Print usage and exit
******************************************************/

Usage:

  msg = MyGetMsg(SysGetMessage(MSG_USAGE,,srcName))
  cmd = 'parse value(msg) with msg '''srcName''' .'
  interpret cmd
  say msg
  say 'SET LANG = ll_cc'
  say me || ' xxx [' || srcPath || '] [' || bootDrive || '] [/u]'
  say ''
  say '   ll_cc = ar_AA | pt_BR | zh_CN | de_DE | da_DK |'
  say '           es_ES | el_GR | fi_FI | fr_FR | iw_IL |'
  say '           it_IT | jp_JP | ko_KR | nl_NL | no_NO |'
  say '           sv_SE | zh_TW | en_US | ...'
  say ''
  say '   xxx = ATI | CHP | DYN | G_V | GEN | MGA | NM | S3 | TRI | VGA | VIRGE'
  say ''
  say '   MORE < ' srcPath || nlv || '\README.TXT'
  say ''
  exit 1


no i polecam zajrzeć do FIXNLS.EXE , siedzi on sobie w \ECS\INSTALL
uprzedzam grzębę cały czas w Instalce EcomStation
--------------------------------------------------------------
co do REXX'a to spora biblioteka i troche narzędzi tutaj http://www.os2site.com
Ostatnio zmieniony 11 wrz 2011, 4:38 przez radio, łącznie zmieniany 2 razy.

Awatar użytkownika

pc.qwerty

Zasłużony użytkownik
Posty: 3272
Rejestracja: 01 lip 2010, 11:28
    Windows Vista Firefox

Post10 wrz 2011, 16:59

Obrazek
There is no cloud. It's just someone else's computer.

Awatar użytkownika

PisarzKsiazkowicz

Moderator
Posty: 2197
Rejestracja: 27 sty 2010, 7:53
    Macintosh Safari

Post15 lis 2015, 22:15

2015 rok. Społeczność eComStation nadal żyje, na horyzoncie jest wersja 2.2, dostępny jest w miarę aktualny port Firefoksa, ponoć szykuje się kolejny śmieszny system tego typu.

Teraz już nic mnie nie zdziwi.
ObrazekObrazek

Awatar użytkownika

pc.qwerty

Zasłużony użytkownik
Posty: 3272
Rejestracja: 01 lip 2010, 11:28
    Windows 7 Chrome

Post15 lis 2015, 23:02

Jakieś linki do poczytania?
There is no cloud. It's just someone else's computer.

Awatar użytkownika

PisarzKsiazkowicz

Moderator
Posty: 2197
Rejestracja: 27 sty 2010, 7:53
    Windows 10 Opera

Post15 lis 2015, 23:19

Nie-tak-stary status update na temat portów Firefoxa, Eclipse i VirtualBoksa:
http://www.os2world.com/index.php?optio ... Itemid=518

Tu najprawdopodobniej są binarki tego portu:
https://github.com/bitwiseworks/mozilla ... OS2_Beta_5

Zapowiedź kolejnego systemu pokroju OS/2:
http://www.arcanoae.com/blue-lion-go/

Poza tym odbył się dość niedawno zjazd fanboyów OS/2, czyli Warpstock:
http://www.warpstock.org/filemgmt/viewcat.php?cid=39

Ciekawe, czy na tym konwencie/zjeździe/whatever pojawiło się więcej osób niż na BeGeistert. Prelekcji na pewno mieli więcej. Oczywiście różnica musi być zauważalna, bo OS/2-eCS jest projektem komercyjnym (mają hajsy!) w przeciwieństwie do takiego hipsterskiego Haiku opierającego się na wsparciu społeczności.

A tu dość stary preview eCS 2.2, który chyba na tym etapie się zatrzymał.
http://www.techrepublic.com/blog/window ... -lives-on/

Moglibyśmy zastanawiać się, czy gdyby Zeta okazała się być jednak legalną i autoryzowaną kontynuacją BeOS'a i nie zostałaby zezłomowana w 2007 roku, otrzymywałaby takie wsparcie jak eCS. Chętnie bym to zobaczył.
ObrazekObrazek

Awatar użytkownika

Onset

Administrator
Posty: 2113
Rejestracja: 06 gru 2008, 19:27
Lokalizacja: multi(0)disk(0)rdisk(0)partition(2)\GDAŃSK
Kontaktowanie:
    Linux Chrome

Post17 lis 2015, 15:40

Nie chce mi się zaglądać i szperać, jaki tam jest format binarek?
Windows 98 supports real multitasking - it can boot and crash simultaneously.
Mój pecet:
Spoiler: pokaż

Obudowa: Modecom ThinkBell, Zasilacz: OCZ ModXStream 600W, Mobo: MSI B85M-G43, Procesor: Intel Core i5-4570 (Haswell) , Wypalarka: Optiarc DVD RW AD-7173A ATA, Grafika: Gigabyte Radeon R9 270x, HDD1: OCZ Vertex 4 128 GB, HDD2:WDC WD5001AALS-00L3B2 (500GB), HDD3+4: WD1002FAEX-00Z3A0 (RAID-0), RAM: Kingston HyperX Black + Red 16GB (2x4 GB + 2x4GB Dual-Channel) CL9, Mocarne chłodzenie: Scythe Mugen II Rev. B.

Retina MacBook Pro Early 2015:
Spoiler: pokaż
Intel Core i5-5257u(Broadwell) @ 2.7 Ghz, RAM: 8 GB @ 1866 MHz DDR3, Intel Iris 6100, 128GB PCI-e SSD

Kto jest online

Użytkownicy przeglądający to forum: Obecnie na forum nie ma żadnego zarejestrowanego użytkownika i 1 gość